Kalkulátory v astronomii

[DejvStorm]

A ta HP Prime má jen RPN nebo i klasiku a jde na ní slušně Python?

Jinak nevíte prosím jestli ta FX-CG50 umožňuje i vykreslování libovolných grafik ala čar, kružnic a tak na přesně dané souřadnice a ne jen třeba nějaké grafy a diagramy podle předvolitelných schémat apod? Možná blbý dotaz, ale grafickou kalkulačku jsem zatím nikdy neměl a rád bych aby to dalo vykreslování poloh planet na obloze, poloh měsíčků Jupitera apod.

[Psion]

HP má jak RPN, tak i klasiku. Python funguje velmi omezeně, alespoň to, co jsem naposledy zkoušel.

Určitě grafický displej Casio umí vykreslovat dle souřadnic, nikdy jsem to nezkoušel, ale bez toho by nedával grafický displej smysl. Program pro měsíce Jupitera jsem dělal na jinou kalkulačku, byla to zábava

[DejvStorm]

Tak počasí poslední týdny opravdu pozorováním moc nepřeje, takže došlo na nějaké ty pokusy s Pythonem v Casio FX-CG50.
Jednak jsem si vyrobil vyhledávač dvojitých tranzitů stínů přes Jupitera, ale obecně i úkazů jupiterových měsíčku, druhak pak přehledy poloh planet pro plánování pozorování bez nutnosti zapínat PC

Takhle k blížícímu se dvojitému tranzitu stínů Io a Europy na ranní obloze 24. července.

DispCap7.png (9.04 KiB) Zobrazeno 8007 x

DispCap6.png (12.79 KiB) Zobrazeno 8007 x

DispCap1.png (7.62 KiB) Zobrazeno 8007 x

[Psion]

Pěkná práce

[Psion]

Kalkulačky HP z 70-tých let se dočkaly oživení novými deskami s rychlejšími CPU. Zajímavostí je nejen možností ukládání až stovek programů v kalkulačce, ale i rozhraním Bluetooth a možností psaní programů v PC a 4 novými funkcemi jako Beep apod. Kalkulačka má i převody mezi číselnými soustavami, hodinami reálného času, možnost tisku na tiskárně, teploměr apod.. Rovněž je zajímavé přepnutí do 5 různých modelů kalkulaček atd. Výpočty jsou 10x rychlejší, než v původní kalkulačce. Na stránce najdete i emulátor HP kalkulaček a řadu informací.

https://www.teenix.org/

https://missingparts.nl/product/hewlett ... or-teenix/

[Psion]

Zajímavé jsou i kalkulačky ze začátku 80-tých a počátku 90-tých let, které obsahovaly progr. jazyk Basic. Hlavními výrobci této konstrukce počítačů byly SHARP (ten se objevil první v r. 1980) a Casio (v r. 1981). V dalších letech se objevily i klony nebo další výrobci jako TI, HP apod. První 8 bitový počítač PC-1500 s obdobným CPU jako byl světoznámý Z80 začal SHARP vyrábět v roce 1981.

Nedávno jsem na eBay objevil prodejce, který doprodával nepoužité počítače Sharp PC-1500A (poprvé se objevil v Japonsku v r.1984). Přístroj dodával i s rozšiřujícím modulem 16kB, který naprosto dostačuje pro veškeré možné programy a rozšiřuje RAM na celkových 22 kB.. Původní počítače měly kolem 2 kB RAM, což bylo poměrně velké omezení.

V Říši hvězd 1985/6 vyšel na straně 116 (PDF str.17) program pro výpočet efemerid od Petra Škody. Další informace a program jsou v číslech 7,8,9. Program je poměrně přesný a odchylky by neměly přesáhnout 10s v RA a 30'' v DEC pokud se použijí korekční členy. Do PC-1211 se celý program nevešel, tak musel být rozdělen na dva (korekční členy zvlášť). Pro PC-1500A je to hračka. Malinko jsem program upravil pro PC1500A, protože původní program je určený pro PC-1211. Rovněž jsem upravil výpočet pro ekvinokcium 2000.

Udělal jsem test na planetce Vesta. Parametry dráhy jsem vzal z JPL Horizons. Výpočty samotné trvají přibližně 10 sekund.

SHARP PC-1500A: RA 5h 45m 48s DEC 20°58' 57''
JPL Horizons Sys.: RA 5h 45m 41s DEC 20°59' 15''

[dvader]

Nádhera!
Dá se do toho nějak program nahrávat? Nebo se to musí ťukat na klávesnici?

[Psion]

Já jsem to tam celé za hodinku naťukal, ale objednal jsem si modul, který umí komunikovat z počítače přes RS232 nebo USB a terminál. Takže se to dá pak napsat na standardním počítači, konvertovat do WAV souboru a nahrát do Sharpu. Totiž tyhle staré počítače měly jediný záznam a to na magnetofonovou pásku, která se dnes dá nahradit čímkoli s přehrávačem WAV souborů. Tady je o tom video, kde používají ASC soubory.

[dvader]

Takže v jejich době dokázaly spolupracovat s kazeťákem jako třeba Spectrum?

[Psion]

Ano, je to podobné, dokonce procesory Sharp a Sinclair ZX Spectrum jsou prakticky stejné.

[Psion]

Samozřejmě, kdo by si chtěl tohle otestovat, nemusí kupovat přístroj, stačí si stáhnout velmi pěkně udělaný emulátor.

http://pocket.free.fr/html/soft/emul_pc-1500a_e.html

[mike]

Tenhle Sharp (nebo velmi podobný) jsem někdy na druhém stupni ZŠ (tj. 1984-88) viděl u kamaráda. Jestli si dobře vzpomínám, byla k tomu i "docking station" s tiskárnou, která tiskla na úzký proužek papíru (podobalo se to tiskárnám na účtenky).

[Psion]

Ano, byla to taková tisková sada včetně komunikace s magnetofonem, špatně se shání samostatně. Je neuvěřitelné, že jej využívala maďarská národní autobusová společnost ještě nedávno jako registrační pokladnu, pravděpodobně k tisku jízdenek

Tady je hezké video k počítači:

[Psion]

Kdyby si chtěl někdo vyzkoušet výpočet souřadnic komety,. planety apod. na obloze s použitím dráhových elementů, tak jsem upravil program pro použití v běžných Basic strojích, tento třeba funguje na Commodore Basic 7. Dráhové elementy jsou uvedeny např. ve SkySafari, podle nich to chodí pěkně. Program by šel upravit na automatické načítání elementů z položek DATA, tedy přednastavit si uživatelské objekty apod.

Kód: Vybrat vše

100 REM PROGRAM UPRAVEN PRO COMMODORE BASIC 7
110 DIM A(29)
120 DG={pi}/180
125 DEF FN ARCS(X1)=ATN(X1/SQR(-X1*X1+1))*(180/{pi})
130 INPUT "TYP:"; AS$ REM Eliptic (E) Parabolic (P)
140 IF AS$ = "P" THEN INPUT "PERIAPSE="; A: GOTO 160
150 INPUT "AXIS="; A: INPUT "ECCENTRICITY="; B
160 INPUT "INCLINATION="; C:INPUT "LONGITUDE ASC.="; D:INPUT "ARGUMENT PERIAPSE="; O
170 PLAY "A"
180 GOSUB 540
190 N = Q
200 E = 23.4457889
210 F = COS(D*DG)
220 G = SIN(D*DG) * COS(E*DG)
230 H = G * TAN(E*DG)
240 I = -SIN(D*DG) * COS(C*DG)
250 J = COS(D*DG) * COS(E*DG) * COS(C*DG) - SIN(C*DG) * SIN(E*DG)
260 K = COS(D*DG) * COS(C*DG) * SIN(E*DG) + SIN(C*DG) * COS(E*DG)
270 Y=F
275 X=I
280 GOSUB 500
285 F=U
290 I=V
295 Y=G
300 X=J
305 GOSUB 500
310 G=U
315 J=V
320 Y=H
325 X=K
330 GOSUB 500
331 H=U
332 K=V
340 PLAY "AB"
350 GOSUB 540
360 GOSUB 720
370 M = (Q - N) / A / SQR(A)
380 IF AS$ = "E" THEN GOSUB 580
390 IF AS$ = "P" THEN GOSUB 650
401 X=SIN(DG*F+O*DG+P*DG)*I*L+R
402 Y=SIN(DG*G+O*DG+P*DG)*J*L+S
403 Z=SIN(DG*H+O*DG+P*DG)*K*L+T
420 GOSUB 500
430 D = SQR(V * V + Z * Z)
440 IF U < 0 THEN LET  U = U + 360
450 REM PEVOD NA STUPN, MINUTY, VTERINY
460 E = U / 15
470 D= FN ARCS(Z/D)
471 S1=INT(E)
472 M1=INT((E-S1)*60)
473 SE=((E-S1)*60-M1)*60
475 S2=INT(D)
476 M2=INT((D-S2)*60)
477 DE=((D-S2)*60-M2)*60
479 PRINT "RA=";S1;"HOD";M1;"MIN";SE;"SEK"
480 PRINT "DEC=";S2;"STU";ABS(M2);"MIN";ABS(DE);"VTE"
490 GOTO 340
500 U = ATN(Y / X) * (180 /{pi})+90*(1-X/ABS(X))*Y/ABS(Y)
520 V = SQR(X * X + Y * Y)
530 RETURN
540 INPUT "DEN="; T:INPUT "MESIC="; S:INPUT "ROK="; R
550 IF S <= 2 THEN R = R - 1: S = S + 12
560 Q = INT(365.25 * R) + INT(30.6001 * (S + 1)) + T - 679003.5 - INT(R / 100)+INT(INT(R/100)/4)
570 RETURN
580 M = .985609 * M: REM "E"
590 E = M
600 L = (M + (180*B/{pi}) * SIN(E*DG) - E) / (1 - B * COS(E*DG))
610 IF ABS(L) > 1E-7 THEN E = E + L: GOTO 600
620 P = 2 * ATN(SQR((1 + B) / (1 - B))* TAN(E*DG/2))*180/{pi}
630 L = A * (1 - B * COS(E*DG))
640 RETURN
650 M = .0364911624 * M
660 E = 0 : REM "P"
670 D = (2 * E * E * E + M) / (E * E + 1) / 3
680 IF ABS(D - E) > 1E-6 THEN E = D: GOTO 670
690 P = 2 * ATN(E)*(180/{pi})
700 L = A * (1 + E * E)
710 RETURN
720 P = 15020
730 L = 36524.2199
740 R = (Q - P - .313) / L
750 S = (51910.423 - Q) / L
760 L = 3600
770 D = (((.018 * S + .302) * S + 2304.25 + 1.396 * R) * S) / L
780 M = (((.42 * S - .426) * S + 2004.682 - .853 * R) * S) / L
790 E = ((.001 * S + .791) * S * S) / L + D
800 R = COS(D*DG) * COS(E*DG) * COS(M*DG) - SIN(E*DG) * SIN(D*DG)
810 S = SIN(D*DG) * COS(E*DG) + COS(D*DG) * SIN(E*DG) * COS(M*DG)
820 T = COS(D*DG) * SIN(M*DG)
830 U = -S
840 V = COS(D*DG) * COS(E*DG) - SIN(D*DG) * SIN(E*DG) * COS(M*DG)
850 W = -SIN(D*DG) * SIN(M*DG)
860 X = -T
870 Y = -SIN(E*DG) * SIN(M*DG)
880 Z = COS(M*DG)
890 D = (Q - P) / 36525
900 M = ((((-33E-7 * D - 15E-5) * D + 35999.04975) * D + 358.47583) / 360)
910 M = (M - INT(M)) * 360
920 A(28) = Q
930 Q = B
940 B = ((126E-9 * D - 418E-7) * D) + .01675104
950 A(27) = A
960 A = 1 + 2E-7
970 GOSUB 590
980 M = (3025E-7 * D + 36000.76892) * D + 279.69668 + P - M
990 B = Q
1000 A = A(27)
1001 C=153.23+22518.7541*D:E=216.571+45037.5082*D:Q=312.69+32964.3577*D
1002 P=(-144E-5*D+445267.1142)*D+350.74
1003 L=L+(543*SIN(C*DG)+1575*SIN(E*DG)+1627*SIN(Q*DG)+3076*COS(P*DG)+927*SIN(65928.7155*D*DG+353.4*DG))*1E-8
1004 M=M+(134*COS(C*DG)+154*COS(E*DG)+200*COS(Q*DG)+179*SIN(P*DG)+178*SIN(231.19*DG+20.2*DG*D))*1E-5
1010 Q = ((503E-9 * D - 164E-8) * D - .0130125) * D + 23.452294
1020 C = L * COS(M*DG)
1030 D = L * SIN(M*DG) * COS(Q*DG)
1040 E = L * SIN(M*DG) * SIN(Q*DG)
1050 R=R*C+U*D+X*E
1051 S=S*C+V*D+Y*E
1052 T=T*C+W*D+Z*E
1080 Q = A(28)
1090 RETURN

[Psion]

Tenhle 8 bit počítač si nikdo asi nepamatuje, ale vyrobil ho sir Sinclair. Cambridge Z88 byl počítač uvedený na trh v roce 1988 firmou Cambridge Research, kterou založil Clive Sinclair poté, co musel prodat svoji Sinclair Research Ltd. Tenkrát to označovali notebook, dnes tomu říkají první iPad. Velikost je v podstatě A4, takže žádný drobeček CPU je známý Z80 na 3.5 MHz, tedy výrazně rychlejší než výše uvedený Sharp. Komunikace přes RS232, rozchodil jsem stařičkou aplikaci pro přenos dat, takže jsem tam portoval s úpravami i výše uvedený program. Kolem tohoto počítače vznikla celá řada dodatečných programů, byl rozšířen operační systém a do dnešních dnů je kolem tohoto aktivní skupina vývojářů.